Perl (1987)

1. Hello, world!

Lege mit StrgAltN eine neue Datei an und schreib hinein:

1
2
3
4

use strict;
use warnings;

print "Hello, World!\n";

Speichere sie mit StrgS als /workspace/hello.pl. Die ersten beiden Zeilen schalten Prüfungen ein: use strict verlangt, dass du jede Variable mit my anlegst, bevor du sie benutzt, und use warnings warnt bei Verdächtigem. Jede Anweisung endet mit einem Semikolon, und \n ist ein Zeilenumbruch.

Visual Studio Code kennt Perl schon und zeigt das Programm farbig, sobald die Datei mit der Endung .pl gespeichert ist:

Skript ausführen

Öffne ein Terminal mit StrgJ und führe das Skript aus:

perl hello.pl

Fehler finden und beheben

Schreib in hello.pl statt print einmal pritn, speichere und führe das Skript wieder aus. Lies, was Perl meldet:

Hier geht es weiter, sobald du deine Antwort oben abgegeben hast.

Perl liest erst das ganze Skript, bevor es etwas ausführt. Ein Wort, das es nicht kennt, gefolgt von einem Text, kann es nicht lesen, und so bricht es ab, bevor die erste Zeile läuft. Denk daran, den Fehler wieder zu beheben.

2. Primfaktorzerlegung

Im zweiten Beispiel zerlegt Perl eine Zahl in ihre Primfaktoren. <STDIN> liest eine Zeile, die du eintippst, mit dem Zeilenumbruch am Ende, und chomp schneidet ihn ab. @factors ist eine Liste, push hängt etwas an. Erstelle eine neue Datei factor.pl:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19

use strict;
use warnings;

print "Please enter the number to factorise:\n";
my $number = <STDIN>;
chomp $number;

# try every divisor from 2 on; a divisor that fits is a prime factor
my @factors;
my $divisor = 2;
while ($number > 1) {
    if ($number % $divisor == 0) {
        push @factors, $divisor;
        $number /= $divisor;
    } else {
        $divisor++;
    }
}
print "Prime factors: @factors\n";

Ein Text, der wie eine Zahl aussieht, ist für Perl eine Zahl, sobald man mit ihm rechnet. Darum kann $number % $divisor rechnen, obwohl <STDIN> einen Text gelesen hat.

3. Bubblesort

Im dritten Beispiel sortiert Perl eine Liste von zehn Zufallszahlen mit Bubblesort. Die Liste heißt @list, ein einzelnes Element darin $list[$i]: Es ist ein einzelner Wert, darum das $. $#list ist der Index des letzten Elements, und @list[$i, $i + 1] = @list[$i + 1, $i] vertauscht zwei Nachbarn in einem Schritt.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18

use strict;
use warnings;

my @list = map { int(rand(100)) } 1 .. 10;
print "Original list: @list\n";

# swap neighbours in the wrong order until a pass swaps none
my $sorted = 0;
until ($sorted) {
    $sorted = 1;
    for my $i (0 .. $#list - 1) {
        if ($list[$i] > $list[$i + 1]) {
            @list[$i, $i + 1] = @list[$i + 1, $i];
            $sorted = 0;
        }
    }
}
print "Sorted list: @list\n";

Speichere es als bubblesort.pl und führe es aus:

4. Zusammenfassung

Du hast an drei Beispielen gesehen, wie ein Perl-Skript aussieht und wie du es ausführst. Seine Stärke zeigt Perl bei Text: Mit regulären Ausdrücken, die in Perl so selbstverständlich sind, dass sie später in fast alle anderen Sprachen übernommen wurden, findet und ersetzt es Muster in jeder Zeile einer Datei. Wie reguläre Ausdrücke funktionieren, zeigt die Aktivität Reguläre Ausdrücke. Die Dokumentation zu Perl findest du unter perldoc.perl.org.